[点晴永久免费OA]ASP调用带参数存储过程的几种方式

admin

2022年6月27日 10:44 本文热度 888

最近有很多的朋友问到调用存储过程的问题，这里简单介绍几种ASP调用带参数存储过程的方法。

1、这也是最简单的方法,两个输入参数，无返回值：
set connection = server.createobject("adodb.connection")
connection.open someDSN
Connection.execute "procname varvalue1, varvalue2"

'将所有对象清为nothing，释放资源
connection.close
set connection = nothing

2、如果要返回 Recordset 集:
set connection = server.createobject("adodb.connection")
connection.open someDSN
set rs = server.createobject("adodb.recordset")
rs.Open "exec procname varvalue1, varvalue2",connection

'将所有对象清为nothing，释放资源
rs.close
connection.close
set rs = nothing
set connection = nothing

3、以上两种方法都不能有返回值，（Recordset除外），如果要得到返回值，需要用Command的方法。
首先说明，返回值有两种。一种是在存储过程中直接return一个值，就象C和VB的函数返回值那样；另一种是可以返回多个值，存
储这些值的变量名称需要在调用参数中先行指定。
这个例子要处理多种参数，输入参数，输出参数，返回记录集以及一个直接返回值（够全了吧？）
存储过程如下：

use pubs
GO

-- 建立存储过程
create procedure sp_PubsTest

-- 定义三个参数变量，注意第三个，特别标记是用于输出
@au_lname varchar (20),
@intID int,
@intIDOut int OUTPUT

AS

select @intIDOut = @intID + 1

select *
from authors
where au_lname LIKE @au_lname + '%'

--直接返回一个值
RETURN @intID + 2

调用该存储过程的asp程序如下：
<%@ Language=VBscript %>
<%
Dim CmdSP
Dim adoRS
Dim adCmdSPStoredProc
Dim adParamReturnValue
Dim adParaminput
Dim adParamOutput
Dim adInteger
Dim iVal
Dim oVal
Dim adoField
Dim adVarChar

'这些值在 VB 中是预定义常量，可以直接调用，但在 VBscript 中没有预定义
adCmdSPStoredProc = 4
adParamReturnValue = 4
adParaminput = 1
adParamOutput = 2
adInteger = 3
adVarChar = 200
iVal = 5
oVal = 3

'建一个command对象
set CmdSP = Server.createObject("ADODB.Command")

'建立连结
CmdSP.ActiveConnection = "Driver={SQL Server};server=(local);Uid=sa;Pwd=;Database=Pubs"

'定义command 对象调用名称
CmdSP.CommandText = "sp_PubsTest"

'设置command调用类型是存储过程 (adCmdSPStoredProc = 4)
CmdSP.CommandType = adCmdSPStoredProc

'往command 对象中加参数
'定义存储过程有直接返回值，并且是个整数，省缺值是4
CmdSP.Parameters.Append CmdSP.createParameter("RETURN_VALUE", adInteger, adParamReturnValue, 4)
'定义一个字符型输入参数
CmdSP.Parameters.Append CmdSP.createParameter("@au_lname", adVarChar, adParaminput, 20, "M")
'定义一个整型输入参数
CmdSP.Parameters.Append CmdSP.createParameter("@intID", adInteger, adParamInput, , iVal)
'定义一个整型输出参数
CmdSP.Parameters.Append CmdSP.createParameter("@intIDOut", adInteger, adParamOutput, oVal)

'运行存储过程，并得到返回记录集
Set adoRS = CmdSP.execute

'把每个记录打印出来，其中的字段是虚拟的，可以不用管
While Not adoRS.EOF

for each adoField in adoRS.Fields
Response.Write adoField.Name & "=" & adoField.Value & " " & vbCRLF
Next
Response.Write " "
adoRS.MoveNext
Wend

'打印两个输出值：
Response.Write "@intIDOut = “ & CmdSP.Parameters("@intIDOut").Value & ""
Response.Write "Return value = " & CmdSP.Parameters("RETURN_VALUE").Value & ""

'大扫除
Set adoRS = nothing
Set CmdSP.ActiveConnection = nothing
Set CmdSP = nothing
%>

asp调用数据库存储过程
<%Set Dataconn = Server.createObject("ADODB.Connection")
'建立连接对象
Dataconn.Open "DSN=SinoTrans;SERVER=APP_SERVER;UID=sa;PWD=;APP=Microsoft(R) Developer Studio;WSID=APP_SERVER;Regional=Yes"
Set cmdTemp = Server.createObject("ADODB.Command")
'建立命令对象
Set rst = Server.createObject("ADODB.Recordset")
'建立记录集对象
cmdTemp.CommandText = "dbo.pd_test" '存储过程名称
cmdTemp.CommandType = 4
'命令类别为4,表示为存储过程
Set cmdTemp.ActiveConnection = Dataconn
Set tmpParam = cmdTemp.createParameter("Return Value", 3, 4, 4)
cmdTemp.Parameters.Append tmpParam
Set tmpParam = cmdTemp.createParameter("@BeginDate", 135, 1, 16, riqi)
'创建输入参数对象
cmdTemp.Parameters.Append tmpParam
rst.Open cmdTemp, , 1, 3
'生成查询结果
%>
这里调用的存储过程为pd_test，这种是ADO中提供的标准方法，但存在一个问题，就是当在存储过程中有两个以上的select语句，但从逻辑上又不可能同时执行的时候，ADO会提示你存储过程中select语句太多，解决方法是直接用ADO的CONNECTION对象的execUTE方法直接执行存储过程，如下：
<%
Set Dataconn = Server.createObject("ADODB.Connection")
'建立连接对象
Dataconn.Open "DSN=SinoTrans;SERVER=APP_SERVER;UID=sa;PWD=;APP=Microsoft(R) Developer Studio;WSID=APP_SERVER;Regional=Yes"
ss = "execUTE dbo.pd_test " & "'" & riqi1 & "'"
Set rs = dataconn.execute(ss)
%>

该文章在 2022/6/27 10:44:54 编辑过

关键字查询

存储

方式

调用

参数

正在查询...

点晴ERP是一款针对中小制造业的专业生产管理软件系统,系统成熟度和易用性得到了国内大量中小企业的青睐。

点晴PMS码头管理系统主要针对港口码头集装箱与散货日常运作、调度、堆场、车队、财务费用、相关报表等业务管理，结合码头的业务特点，围绕调度、堆场作业而开发的。集技术的先进性、管理的有效性于一体，是物流码头及其他港口类企业的高效ERP管理信息系统。

点晴WMS仓储管理系统提供了货物产品管理,销售管理,采购管理,仓储管理,仓库管理,保质期管理,货位管理,库位管理,生产管理,WMS管理系统,标签打印,条形码,二维码管理,批号管理软件。

点晴免费OA是一款软件和通用服务都免费，不限功能、不限时间、不限用户的免费OA协同办公管理系统。